home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / chisqr_cvf.pro < prev    next >
Text File  |  1997-07-08  |  2KB  |  72 lines
  1. ;$Id: chisqr_cvf.pro,v 1.3 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1994-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5. ;+
  6. ; NAME:
  7. ;       CHISQR_CVF
  8. ;
  9. ; PURPOSE: 
  10. ;    This function computes the cutoff value (v) such that:
  11. ;                   Probability(X > v) = p
  12. ;       where X is a random variable from the Chi-square distribution
  13. ;       with (df) degrees of freedom. 
  14. ;
  15. ; CATEGORY:
  16. ;       Statistics.
  17. ; 
  18. ; CALLING SEQUENCE:
  19. ;       Result = chisqr_cvf(P, DF)
  20. ;
  21. ; INPUTS:
  22. ;       P:    A non-negative scalar, in the interval [0.0, 1.0], of type
  23. ;             float or double that specifies the probability of occurance 
  24. ;             or success.
  25. ;
  26. ;      DF:    A positive scalar of type integer, float or double that 
  27. ;             specifies the degrees of freedom of the Chi-square distribution.
  28. ;
  29. ; EXAMPLE:
  30. ;       Compute the cutoff value (v) such that Probability(X > v) = 0.100
  31. ;       from the Chi-square distribution with (DF = 3) degrees of freedom. 
  32. ;       The result should be 6.25139
  33. ;         result = chisqr_cvf(0.100, 3) 
  34. ;
  35. ; REFERENCE:
  36. ;       ADVANCED ENGINEERING MATHEMATICS (seventh edition)
  37. ;       Erwin Kreyszig
  38. ;       ISBN 0-471-55380-8
  39. ;
  40. ; MODIFICATION HISTORY:
  41. ;       Modified by:  GGS, RSI, July 1994
  42. ;                     Minor changes to code. New documentation header.
  43. ;-
  44.  
  45. function chisqr_cvf, p, df
  46.  
  47.   on_error, 2  ;Return to caller if error occurs.
  48.  
  49.   if p lt 0. or p gt 1. then message, $
  50.     'p must be in the interval [0.0, 1.0]'
  51.   if p eq 0 then return, 1.0e12
  52.   if p eq 1 then return, 0.0
  53.   if df lt 0 then message, $
  54.     'Degrees of freedom must be positive.'
  55.  
  56.   case 1 of
  57.     df eq 1: up = 300.0 
  58.     df eq 2: up = 100.0 
  59.     df gt 2 and df le 5: up = 30.0
  60.     df gt 5 and df le 14: up = 20.0
  61.     else: up = 12.0
  62.   endcase
  63.   below = 0
  64.   while chisqr_pdf(up, df) lt (1 - p) do begin
  65.       below = up
  66.       up = 2 * up
  67.   endwhile
  68.  
  69.   return, bisect_pdf([1-p, df], 'chisqr_pdf', up, below)
  70. end
  71.  
  72.